home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Cream of the Crop 22
/
Cream of the Crop 22.iso
/
utility
/
tsbat50.zip
/
SAMESIZE.BAT
< prev
next >
Wrap
DOS Batch File
|
1996-08-24
|
2KB
|
56 lines
@echo off
echo.
echo ┌───────────────────────────────────────────────────┐
echo │ Find the files of the same size on a drive │
echo │ Copyright by Prof. Timo Salmi Sat 24-Aug-96 │
echo │ Email: ts@uwasa.fi WWW: http://www.uwasa.fi/~ts/ │
echo └───────────────────────────────────────────────────┘
echo.
set drive_=%1
set auxdr_=R:
if "%drive_%"=="" goto _usage
rem Auxiliary drive
if not exist %auxdr_%\nul goto _err1
rem The drive to be scanned for size duplicates
if not exist %drive_%\nul goto _err2
rem The "engine"
dir %drive_%\ /s | find /V "<DIR>" > %auxdr_%samesiz1.$$$
find /V "Directory of" < %auxdr_%samesiz1.$$$ > %auxdr_%samesiz2.$$$
find /V "Total files listed:" < %auxdr_%samesiz2.$$$ > %auxdr_%samesiz1.$$$
find /V " file(s)" < %auxdr_%samesiz1.$$$ > %auxdr_%samesiz2.$$$
find /V " bytes free" < %auxdr_%samesiz2.$$$ > %auxdr_%samesiz1.$$$
find /V "Volume in drive" < %auxdr_%samesiz1.$$$ > %auxdr_%samesiz2.$$$
find /V "Volume Serial Number is" < %auxdr_%samesiz2.$$$ > %auxdr_%samesiz1.$$$
find ":" < %auxdr_%samesiz1.$$$ > %auxdr_%samesiz2.$$$
sort /+14 < %auxdr_%samesiz2.$$$ > %auxdr_%samesiz1.$$$
rem Present the results
type %auxdr_%samesiz1.$$$
copy %auxdr_%samesiz1.$$$ %auxdr_%samesize.rpt > nul
echo.
echo The results are stored in %auxdr_%samesize.rpt
rem Delete the auxiliary files
if exist %auxdr_%samesiz1.$$$ del %auxdr_%samesiz1.$$$
if exist %auxdr_%samesiz2.$$$ del %auxdr_%samesiz2.$$$
goto _end
:_err1
echo Auxiliary drive %auxdr_% not found
echo Reconfigure the batch variable auxdr_ to point to a valid drive on your system
goto _end
:_err2
echo Invalid drive %drive_%
:_usage
echo Usage %0 Drive:
:_end
set drive_=
set auxdr_=